ReCo.jl/graphics/radial_distribution.jl

using Luxor
using Random: Random
using StaticArrays: SVector

using ReCo: ReCo

function gen_rdf_graphics()
    Random.seed!(1)

    box_length = 100
    box_length = 100

    graphics_export_dir = "exports/graphics"
    mkpath(graphics_export_dir)

    Drawing(box_length, box_length, "$graphics_export_dir/rdf_shells.pdf")
    origin()

    particle_radius = 6
    Δr = 2.4 * particle_radius

    setcolor("blue")
    circle(Point(0, 0), particle_radius, :fill)

    N = 50

    selected_shell_ind = 3
    selected_lower_radius = (selected_shell_ind - 1) * Δr

    particle_cs = Vector{SVector{2,Float64}}(undef, N)

    distance_limit = 0.99 * 2 * particle_radius

    x = y = distance = 0.0

    for p1_ind in 1:N
        while true
            x = (rand() - 0.5) * box_length
            y = (rand() - 0.5) * box_length

            p1_c = SVector(x, y)

            distance = ReCo.norm2d(p1_c)

            no_collision = true

            if distance >= distance_limit
                for p2_ind in 1:(p1_ind - 1)
                    if ReCo.norm2d(p1_c - particle_cs[p2_ind]) < distance_limit
                        no_collision = false

                        break
                    end
                end

                if no_collision
                    particle_cs[p1_ind] = p1_c
                    break
                end
            end
        end

        if selected_lower_radius <= distance < selected_lower_radius + Δr
            setcolor("green")
        else
            setcolor("orange")
        end

        circle(x, y, particle_radius, :fill)
    end

    setcolor("black")
    setline(0.2)
    for shell_ind in 1:ceil(Int64, (box_length - 1) / 2 / Δr)
        circle(Point(0, 0), shell_ind * Δr, :stroke)
    end

    setcolor("red")
    setline(0.3)
    line(Point(0, 0), Point(Δr, 0), :stroke)

    fontsize(4.5)
    text("Δr", Point(0.44 * Δr, -0.05 * Δr))

    finish()

    return nothing
end